# HG changeset patch
# User Maxim Dounin <mdounin@mdounin.ru>
# Date 1352432797 -14400
# Node ID 462d89f5732a13569b53545527bf2a266b0b0452
# Parent  5d178e27037ccf34bb31b645ca08ddee49420339
Tests: request body and chunked transfer encoding tests.

diff --git a/body.t b/body.t
new file mode 100644
--- /dev/null
+++ b/body.t
@@ -0,0 +1,147 @@
+#!/usr/bin/perl
+
+# (C) Maxim Dounin
+
+# Tests for nginx request body reading.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+use Socket qw/ CRLF /;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+my $t = Test::Nginx->new()->has(qw/http proxy rewrite/)->plan(10);
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon         off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080;
+        server_name  localhost;
+
+        client_header_buffer_size 1k;
+
+        location / {
+            client_body_buffer_size 2k;
+            add_header X-Body "$request_body";
+            add_header X-Body-File "$request_body_file";
+            proxy_pass http://127.0.0.1:8081;
+        }
+        location /b {
+            client_body_buffer_size 2k;
+            client_body_in_file_only on;
+            add_header X-Body "$request_body";
+            add_header X-Body-File "$request_body_file";
+            proxy_pass http://127.0.0.1:8081;
+        }
+        location /single {
+            client_body_in_single_buffer on;
+            add_header X-Body "$request_body";
+            add_header X-Body-File "$request_body_file";
+            proxy_pass http://127.0.0.1:8081;
+        }
+        location /discard {
+            return 200 "TEST\n";
+        }
+    }
+
+    server {
+        listen       127.0.0.1:8081;
+        server_name  localhost;
+
+        location / {
+            return 200 "TEST\n";
+        }
+    }
+}
+
+EOF
+
+$t->run();
+
+###############################################################################
+
+unlike(http_get('/'), qr/X-Body:/ms, 'no body');
+
+like(http_get_body('/', '0123456789'),
+	qr/X-Body: 0123456789\x0d?$/ms, 'body');
+
+like(http_get_body('/', '0123456789' x 128),
+	qr/X-Body: (0123456789){128}\x0d?$/ms, 'body in two buffers');
+
+like(http_get_body('/', '0123456789' x 512),
+	qr/X-Body-File/ms, 'body in file');
+
+like(read_body_file(http_get_body('/b', '0123456789' x 512)),
+	qr/^(0123456789){512}$/s, 'body in file only');
+
+like(http_get_body('/single', '0123456789' x 128),
+	qr/X-Body: (0123456789){128}\x0d?$/ms, 'body in single buffer');
+
+# pipelined requests
+
+like(http_get_body('/', '0123456789', '0123456789' x 128, '0123456789' x 512,
+        'foobar'), qr/X-Body: foobar\x0d?$/ms, 'body pipelined');
+like(http_get_body('/', '0123456789' x 128, '0123456789' x 512, '0123456789',
+        'foobar'), qr/X-Body: foobar\x0d?$/ms, 'body pipelined 2');
+
+like(http_get_body('/discard', '0123456789', '0123456789' x 128,
+	'0123456789' x 512, 'foobar'), qr/(TEST.*){4}/ms,
+	'body discard');
+like(http_get_body('/discard', '0123456789' x 128, '0123456789' x 512,
+	'0123456789', 'foobar'), qr/(TEST.*){4}/ms,
+	'body discard 2');
+
+###############################################################################
+
+sub read_body_file {
+	my ($r) = @_;
+	return '' unless $r =~ m/X-Body-File: (.*)/;
+	open FILE, $1
+		or return "$!";
+	local $/;
+	my $content = <FILE>;
+	close FILE;
+	return $content;
+}
+
+sub http_get_body {
+	my $uri = shift;
+	my $last = pop;
+	return http( join '', (map {
+		my $body = $_;
+		"GET $uri HTTP/1.1" . CRLF
+		. "Host: localhost" . CRLF
+		. "Content-Length: " . (length $body) . CRLF . CRLF
+		. $body
+	} @_),
+		"GET $uri HTTP/1.1" . CRLF
+		. "Host: localhost" . CRLF
+		. "Connection: close" . CRLF
+		. "Content-Length: " . (length $last) . CRLF . CRLF
+		. $last
+	);
+}
+
+###############################################################################
diff --git a/body_chunked.t b/body_chunked.t
new file mode 100644
--- /dev/null
+++ b/body_chunked.t
@@ -0,0 +1,154 @@
+#!/usr/bin/perl
+
+# (C) Maxim Dounin
+
+# Tests for nginx request body reading, with chunked transfer-coding.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+use Socket qw/ CRLF /;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+my $t = Test::Nginx->new()->has(qw/http proxy rewrite/)->plan(9);
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon         off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080;
+        server_name  localhost;
+
+        client_header_buffer_size 1k;
+
+        location / {
+            client_body_buffer_size 2k;
+            add_header X-Body "$request_body";
+            add_header X-Body-File "$request_body_file";
+            proxy_pass http://127.0.0.1:8081;
+        }
+        location /b {
+            client_body_buffer_size 2k;
+            client_body_in_file_only on;
+            add_header X-Body "$request_body";
+            add_header X-Body-File "$request_body_file";
+            proxy_pass http://127.0.0.1:8081;
+        }
+        location /single {
+            client_body_in_single_buffer on;
+            add_header X-Body "$request_body";
+            add_header X-Body-File "$request_body_file";
+            proxy_pass http://127.0.0.1:8081;
+        }
+        location /discard {
+            return 200 "TEST\n";
+        }
+    }
+
+    server {
+        listen       127.0.0.1:8081;
+        server_name  localhost;
+
+        location / {
+            return 200 "TEST\n";
+        }
+    }
+}
+
+EOF
+
+$t->run();
+
+###############################################################################
+
+TODO: {
+local $TODO = 'not yet';
+
+like(http_get_body('/', '0123456789'),
+	qr/X-Body: 0123456789\x0d?$/ms, 'body');
+
+like(http_get_body('/', '0123456789' x 128),
+	qr/X-Body: (0123456789){128}\x0d?$/ms, 'body in two buffers');
+
+like(http_get_body('/', '0123456789' x 512),
+	qr/X-Body-File/ms, 'body in file');
+
+like(read_body_file(http_get_body('/b', '0123456789' x 512)),
+	qr/^(0123456789){512}$/s, 'body in file only');
+
+like(http_get_body('/single', '0123456789' x 128),
+	qr/X-Body: (0123456789){128}\x0d?$/ms, 'body in single buffer');
+
+# pipelined requests
+
+like(http_get_body('/', '0123456789', '0123456789' x 128, '0123456789' x 512,
+	'foobar'), qr/X-Body: foobar\x0d?$/ms, 'chunked body pipelined');
+like(http_get_body('/', '0123456789' x 128, '0123456789' x 512, '0123456789',
+	'foobar'), qr/X-Body: foobar\x0d?$/ms, 'chunked body pipelined 2');
+
+like(http_get_body('/discard', '0123456789', '0123456789' x 128,
+	'0123456789' x 512, 'foobar'), qr/(TEST.*){4}/ms,
+	'chunked body discard');
+like(http_get_body('/discard', '0123456789' x 128, '0123456789' x 512,
+	'0123456789', 'foobar'), qr/(TEST.*){4}/ms,
+	'chunked body discard 2');
+
+}
+
+###############################################################################
+
+sub read_body_file {
+	my ($r) = @_;
+	return '' unless $r =~ m/X-Body-File: (.*)/;
+	open FILE, $1
+		or return "$!";
+	local $/;
+	my $content = <FILE>;
+	close FILE;
+	return $content;
+}
+
+sub http_get_body {
+	my $uri = shift;
+	my $last = pop;
+	return http( join '', (map {
+		my $body = $_;
+		"GET $uri HTTP/1.1" . CRLF
+		. "Host: localhost" . CRLF
+		. "Transfer-Encoding: chunked" . CRLF . CRLF
+		. sprintf("%x", length $body) . CRLF
+		. $body . CRLF
+		. "0" . CRLF . CRLF
+	} @_),
+		"GET $uri HTTP/1.1" . CRLF
+		. "Host: localhost" . CRLF
+		. "Connection: close" . CRLF
+		. "Transfer-Encoding: chunked" . CRLF . CRLF
+		. sprintf("%x", length $last) . CRLF
+		. $last . CRLF
+		. "0" . CRLF . CRLF
+	);
+}
+
+###############################################################################
diff --git a/dav_chunked.t b/dav_chunked.t
new file mode 100644
--- /dev/null
+++ b/dav_chunked.t
@@ -0,0 +1,119 @@
+#!/usr/bin/perl
+
+# (C) Maxim Dounin
+
+# Tests for nginx dav module with chunked request body.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+use Socket qw/ CRLF /;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+my $t = Test::Nginx->new()->has(qw/http dav/)->plan(6);
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon         off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080;
+        server_name  localhost;
+
+        client_header_buffer_size 1k;
+        client_body_buffer_size 2k;
+
+        location / {
+            dav_methods PUT;
+        }
+    }
+}
+
+EOF
+
+$t->run();
+
+###############################################################################
+
+TODO: {
+local $TODO = 'not yet';
+
+my $r;
+
+$r = http(<<EOF);
+PUT /file HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+a
+1234567890
+0
+
+EOF
+
+like($r, qr/201 Created.*(Content-Length|\x0d\0a0\x0d\x0a)/ms, 'put chunked');
+is(read_file($t->testdir() . '/file'), '1234567890', 'put content');
+
+$r = http(<<EOF);
+PUT /file HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+0
+
+EOF
+
+like($r, qr/204 No Content/, 'put chunked empty');
+is(read_file($t->testdir() . '/file'), '', 'put empty content');
+
+my $body = ('a' . CRLF . '1234567890' . CRLF) x 1024 . '0' . CRLF . CRLF;
+
+$r = http(<<EOF);
+PUT /file HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+$body
+EOF
+
+like($r, qr/204 No Content/, 'put chunked big');
+is(read_file($t->testdir() . '/file'), '1234567890' x 1024, 'put big content');
+
+}
+
+###############################################################################
+
+sub read_file {
+	my ($file) = @_;
+	open FILE, $file
+		or return "$!";
+	local $/;
+	my $content = <FILE>;
+	close FILE;
+	return $content;
+}
+
+###############################################################################
diff --git a/fastcgi_body.t b/fastcgi_body.t
new file mode 100644
--- /dev/null
+++ b/fastcgi_body.t
@@ -0,0 +1,134 @@
+#!/usr/bin/perl
+
+# (C) Maxim Dounin
+
+# Test for fastcgi backend with chunked request body.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+eval { require FCGI; };
+plan(skip_all => 'FCGI not installed') if $@;
+plan(skip_all => 'win32') if $^O eq 'MSWin32';
+
+my $t = Test::Nginx->new()->has(qw/http fastcgi/)->plan(5)
+	->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon         off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080;
+        server_name  localhost;
+
+        location / {
+            fastcgi_pass 127.0.0.1:8081;
+            fastcgi_param REQUEST_URI $request_uri;
+            fastcgi_param CONTENT_LENGTH $content_length;
+        }
+    }
+}
+
+EOF
+
+$t->run_daemon(\&fastcgi_daemon);
+$t->run();
+
+###############################################################################
+
+like(http_get('/'), qr/X-Body: /, 'fastcgi no body');
+
+like(http_get_length('/', ''), qr/X-Body: /, 'fastcgi empty body');
+like(http_get_length('/', 'foobar'), qr/X-Body: foobar/, 'fastcgi body');
+
+TODO: {
+local $TODO = 'not yet';
+
+like(http(<<EOF), qr/X-Body: foobar/, 'fastcgi chunked');
+GET / HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+6
+foobar
+0
+
+EOF
+
+like(http(<<EOF), qr/X-Body: /, 'fastcgi empty chunked');
+GET / HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+0
+
+EOF
+
+}
+
+###############################################################################
+
+sub http_get_length {
+        my ($url, $body) = @_;
+	my $length = length $body;
+        return http(<<EOF);
+GET $url HTTP/1.1
+Host: localhost
+Connection: close
+Content-Length: $length
+
+$body
+EOF
+}
+
+###############################################################################
+
+sub fastcgi_daemon {
+	my $socket = FCGI::OpenSocket('127.0.0.1:8081', 5);
+	my $request = FCGI::Request(\*STDIN, \*STDOUT, \*STDERR, \%ENV,
+		$socket);
+
+	my $count;
+	my $body;
+
+	while( $request->Accept() >= 0 ) {
+		$count++;
+		read(STDIN, $body, $ENV{'CONTENT_LENGTH'});
+
+		print <<EOF;
+Location: http://127.0.0.1:8080/redirect
+Content-Type: text/html
+X-Body: $body
+
+SEE-THIS
+$count
+EOF
+	}
+
+	FCGI::CloseSocket($socket);
+}
+
+###############################################################################
diff --git a/scgi_body.t b/scgi_body.t
new file mode 100644
--- /dev/null
+++ b/scgi_body.t
@@ -0,0 +1,136 @@
+#!/usr/bin/perl
+
+# (C) Maxim Dounin
+
+# Test for scgi backend with chunked request body.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+eval { require SCGI; };
+plan(skip_all => 'SCGI not installed') if $@;
+
+my $t = Test::Nginx->new()->has(qw/http scgi/)->plan(5)
+	->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon         off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080;
+        server_name  localhost;
+
+        location / {
+            scgi_pass 127.0.0.1:8081;
+            scgi_param SCGI 1;
+            scgi_param REQUEST_URI $request_uri;
+        }
+    }
+}
+
+EOF
+
+$t->run_daemon(\&scgi_daemon);
+$t->run();
+
+###############################################################################
+
+
+like(http_get('/'), qr/X-Body: /, 'scgi no body');
+
+like(http_get_length('/', ''), qr/X-Body: /, 'scgi empty body');
+like(http_get_length('/', 'foobar'), qr/X-Body: foobar/, 'scgi body');
+
+TODO: {
+local $TODO = 'not yet';
+
+like(http(<<EOF), qr/X-Body: foobar/, 'scgi chunked');
+GET / HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+6
+foobar
+0
+
+EOF
+
+like(http(<<EOF), qr/X-Body: /, 'scgi empty chunked');
+GET / HTTP/1.1
+Host: localhost
+Connection: close
+Transfer-Encoding: chunked
+
+0
+
+EOF
+
+}
+
+###############################################################################
+
+sub http_get_length {
+        my ($url, $body) = @_;
+        my $length = length $body;
+        return http(<<EOF);
+GET $url HTTP/1.1
+Host: localhost
+Connection: close
+Content-Length: $length
+
+$body
+EOF
+}
+
+###############################################################################
+
+sub scgi_daemon {
+	my $server = IO::Socket::INET->new(
+		Proto => 'tcp',
+		LocalHost => '127.0.0.1:8081',
+		Listen => 5,
+		Reuse => 1
+	)
+		or die "Can't create listening socket: $!\n";
+
+	my $scgi = SCGI->new($server, blocking => 1);
+	my $body;
+
+	while (my $request = $scgi->accept()) {
+		$request->read_env();
+		read($request->connection, $body,
+			$request->env->{CONTENT_LENGTH});
+
+		$request->connection()->print(<<EOF);
+Location: http://127.0.0.1:8080/redirect
+Content-Type: text/html
+X-Body: $body
+
+SEE-THIS
+EOF
+	}
+}
+
+###############################################################################