Mercurial > hg > mercurial-crew-with-dirclash

view contrib/vim/hg-menu.vim @ 5440:f9b0e4f023c4

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
findcopies: fix rename bug We've fiddled with this line several times, and an old bug has reappeared from it. Let's take a peek at the history. The original "or" (rev 3674, in 0.9.2 and 0.9.3): http://www.selenic.com/hg/rev/9103dab96093 Then I changed it to an "and" to fix a bug (rev 4304): http://www.selenic.com/hg/rev/4787e2b0dd03 Then for reasons now lost in the mists of time, I dropped half (rev 4399): http://www.selenic.com/hg/rev/93652499bed3 Then we added back the "or" (rev 4416, in 0.9.4): http://www.selenic.com/hg/rev/bb1800a7d7e1 So it seems it ought to be "and".
author Matt Mackall <mpm@selenic.com>
date Mon, 08 Oct 2007 18:47:22 -0500
parents ea7b982b6c08
children
line wrap: on
line source

" vim600: set foldmethod=marker:
" =============================================================================
"  Name Of File: hg-menu.vim
"   Description: Interface to Mercurial Version Control.
"        Author: Steve Borho (modified Jeff Lanzarotta's RCS script)
"          Date: Wednesday, October 5, 2005
"       Version: 0.1.0
"     Copyright: None.
"         Usage: These command and gui menu displays useful hg functions
" Configuration: Your hg executable must be in your path.
" =============================================================================

" Section: Init {{{1
if exists("loaded_hg_menu")
  finish
endif
let loaded_hg_menu = 1

" Section: Menu Options {{{1
if has("gui")
"  amenu H&G.Commit\ File<Tab>,ci :!hg commit %<CR>:e!<CR>
"  amenu H&G.Commit\ All<Tab>,call :!hg commit<CR>:e!<CR>
"  amenu H&G.-SEP1-        <nul>
  amenu H&G.Add<Tab>\\add :!hg add %<CR><CR>
  amenu H&G.Forget\ Add<Tab>\\fgt :!hg forget %<CR><CR>
  amenu H&G.Show\ Differences<Tab>\\diff :call ShowResults("FileDiff", "hg\ diff")<CR><CR>
  amenu H&G.Revert\ to\ Last\ Version<Tab>\\revert :!hg revert %<CR>:e!<CR>
  amenu H&G.Show\ History<Tab>\\log :call ShowResults("FileLog", "hg\ log")<CR><CR>
  amenu H&G.Annotate<Tab>\\an :call ShowResults("annotate", "hg\ annotate")<CR><CR>
  amenu H&G.-SEP1-        <nul>
  amenu H&G.Repo\ Status<Tab>\\stat :call ShowResults("RepoStatus", "hg\ status")<CR><CR>
  amenu H&G.Pull<Tab>\\pull :!hg pull<CR>:e!<CR>
  amenu H&G.Update<Tab>\\upd :!hg update<CR>:e!<CR>
endif

" Section: Mappings {{{1
if(v:version >= 600)
  " The default Leader is \ 'backslash'
  map <Leader>add       :!hg add %<CR><CR>
  map <Leader>fgt       :!hg forget %<CR><CR>
  map <Leader>diff      :call ShowResults("FileDiff", "hg\ diff")<CR><CR>
  map <Leader>revert    :!hg revert %<CR>:e!<CR>
  map <Leader>log       :call ShowResults("FileLog", "hg\ log")<CR><CR>
  map <Leader>an        :call ShowResults("annotate", "hg\ annotate")<CR><CR>
  map <Leader>stat      :call ShowResults("RepoStatus", "hg\ status")<CR><CR>
  map <Leader>upd       :!hg update<CR>:e!<CR>
  map <Leader>pull      :!hg pull<CR>:e!<CR>
else
  " pre 6.0, the default Leader was a comma
  map ,add          :!hg add %<CR><CR>
  map ,fgt          :!hg forget %<CR><CR>
  map ,diff         :call ShowResults("FileDiff", "hg\ diff")<CR><CR>
  map ,revert       :!hg revert<CR>:e!<CR>
  map ,log          :call ShowResults("FileLog", "hg\ log")<CR><CR>
  map ,an           :call ShowResults("annotate", "hg\ annotate")<CR><CR>
  map ,stat         :call ShowResults("RepoStatus", "hg\ status")<CR><CR>
  map ,upd          :!hg update<CR>:e!<CR>
  map ,pull         :!hg pull<CR>:e!<CR>
endif

" Section: Functions {{{1
" Show the log results of the current file with a revision control system.
function! ShowResults(bufferName, cmdName)
  " Modify the shortmess option:
  " A  don't give the "ATTENTION" message when an existing swap file is
  "    found.
  set shortmess+=A

  " Get the name of the current buffer.
  let currentBuffer = bufname("%")

  " If a buffer with the name rlog exists, delete it.
  if bufexists(a:bufferName)
    execute 'bd! ' a:bufferName
  endif

  " Create a new buffer.
  execute 'new ' a:bufferName

  " Execute the command.
  execute 'r!' a:cmdName ' ' currentBuffer

  " Make is so that the file can't be edited.
  setlocal nomodified
  setlocal nomodifiable
  setlocal readonly

  " Go to the beginning of the buffer.
  execute "normal 1G"

  " Restore the shortmess option.
  set shortmess-=A
endfunction