Mercurial > hg > nginx-tests

comparison stream_upstream.t @ 556:97d89d9ab4ed

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Tests: basic stream upstream tests.
author Sergey Kandaurov <pluknet@nginx.com>
date Wed, 22 Apr 2015 16:59:40 +0300
parents
children cd3e32d9997e
comparison
equal deleted inserted replaced
555:ba6cc90e3d67 556:97d89d9ab4ed
1 #!/usr/bin/perl
2
3 # (C) Sergey Kandaurov
4 # (C) Nginx, Inc.
5
6 # Stream tests for upstream module and balancers.
7
8 ###############################################################################
9
10 use warnings;
11 use strict;
12
13 use Test::More;
14
15 use IO::Select;
16
17 BEGIN { use FindBin; chdir($FindBin::Bin); }
18
19 use lib 'lib';
20 use Test::Nginx;
21
22 ###############################################################################
23
24 select STDERR; $| = 1;
25 select STDOUT; $| = 1;
26
27 my $t = Test::Nginx->new()->has(qw/stream/)->plan(4)
28 ->write_file_expand('nginx.conf', <<'EOF');
29
30 %%TEST_GLOBALS%%
31
32 daemon off;
33
34 events {
35 }
36
37 stream {
38 upstream u {
39 server 127.0.0.1:8087;
40 server 127.0.0.1:8088;
41 }
42
43 upstream u2 {
44 server 127.0.0.1:8089 down;
45 server 127.0.0.1:8089;
46 server 127.0.0.1:8087;
47 server 127.0.0.1:8088;
48 }
49
50 upstream u3 {
51 server 127.0.0.1:8087;
52 server 127.0.0.1:8088 weight=2;
53 }
54
55 upstream u4 {
56 server 127.0.0.1:8089;
57 server 127.0.0.1:8087 backup;
58 }
59
60 proxy_connect_timeout 2s;
61
62 server {
63 listen 127.0.0.1:8081;
64 proxy_pass u;
65 }
66
67 server {
68 listen 127.0.0.1:8082;
69 proxy_pass u2;
70 }
71
72 server {
73 listen 127.0.0.1:8083;
74 proxy_pass u3;
75 }
76
77 server {
78 listen 127.0.0.1:8084;
79 proxy_pass u4;
80 }
81 }
82
83 EOF
84
85 $t->run_daemon(\&stream_daemon, 8087);
86 $t->run_daemon(\&stream_daemon, 8088);
87 $t->run();
88
89 $t->waitforsocket('127.0.0.1:8087');
90 $t->waitforsocket('127.0.0.1:8088');
91
92 ###############################################################################
93
94 is(many('.', 30, peer => '127.0.0.1:8081'), '8087: 15, 8088: 15', 'balanced');
95 is(many('.', 30, peer => '127.0.0.1:8082'), '8087: 15, 8088: 15', 'failures');
96 is(many('.', 30, peer => '127.0.0.1:8083'), '8087: 10, 8088: 20', 'weight');
97 is(many('.', 30, peer => '127.0.0.1:8084'), '8087: 30', 'backup');
98
99 ###############################################################################
100
101 sub many {
102 my ($data, $count, %opts) = @_;
103 my (%ports, $peer);
104
105 $peer = $opts{peer};
106
107 for (1 .. $count) {
108 if (stream_get($data, $peer) =~ /(\d+)/) {
109 $ports{$1} = 0 unless defined $ports{$1};
110 $ports{$1}++;
111 }
112 }
113
114 return join ', ', map { $_ . ": " . $ports{$_} } sort keys %ports;
115 }
116
117 sub stream_get {
118 my ($data, $peer) = @_;
119
120 my $s = stream_connect($peer);
121 stream_write($s, $data);
122 my $r = stream_read($s);
123
124 $s->close;
125 return $r;
126 }
127
128 sub stream_connect {
129 my $peer = shift;
130 my $s = IO::Socket::INET->new(
131 Proto => 'tcp',
132 PeerAddr => $peer
133 )
134 or die "Can't connect to nginx: $!\n";
135
136 return $s;
137 }
138
139 sub stream_write {
140 my ($s, $message) = @_;
141
142 local $SIG{PIPE} = 'IGNORE';
143
144 $s->blocking(0);
145 while (IO::Select->new($s)->can_write(1.5)) {
146 my $n = $s->syswrite($message);
147 last unless $n;
148 $message = substr($message, $n);
149 last unless length $message;
150 }
151
152 if (length $message) {
153 $s->close();
154 }
155 }
156
157 sub stream_read {
158 my ($s) = @_;
159 my ($buf);
160
161 $s->blocking(0);
162 if (IO::Select->new($s)->can_read(3)) {
163 $s->sysread($buf, 1024);
164 };
165
166 log_in($buf);
167 return $buf;
168 }
169
170 ###############################################################################
171
172 sub stream_daemon {
173 my ($port) = @_;
174
175 my $server = IO::Socket::INET->new(
176 Proto => 'tcp',
177 LocalAddr => '127.0.0.1',
178 LocalPort => $port,
179 Listen => 5,
180 Reuse => 1
181 )
182 or die "Can't create listening socket: $!\n";
183
184 my $sel = IO::Select->new($server);
185
186 local $SIG{PIPE} = 'IGNORE';
187
188 while (my @ready = $sel->can_read) {
189 foreach my $fh (@ready) {
190 if ($server == $fh) {
191 my $new = $fh->accept;
192 $new->autoflush(1);
193 $sel->add($new);
194
195 } elsif (stream_handle_client($fh)) {
196 $sel->remove($fh);
197 $fh->close;
198 }
199 }
200 }
201 }
202
203 sub stream_handle_client {
204 my ($client) = @_;
205
206 log2c("(new connection $client)");
207
208 $client->sysread(my $buffer, 65536) or return 1;
209
210 log2i("$client $buffer");
211
212 $buffer = $client->sockport();
213
214 log2o("$client $buffer");
215
216 $client->syswrite($buffer);
217
218 return 1;
219 }
220
221 sub log2i { Test::Nginx::log_core('|| <<', @_); }
222 sub log2o { Test::Nginx::log_core('|| >>', @_); }
223 sub log2c { Test::Nginx::log_core('||', @_); }
224
225 ###############################################################################