# HG changeset patch
# User Sergey Kandaurov <pluknet@nginx.com>
# Date 1449661474 -10800
# Node ID faf2e460b9518110f2467df980ee8b1165597854
# Parent  55ca38e1a3d9fc84dbcdb46019e4de938e77beff
Tests: basic proxy tests with unix socket.

diff --git a/proxy_unix.t b/proxy_unix.t
new file mode 100644
--- /dev/null
+++ b/proxy_unix.t
@@ -0,0 +1,151 @@
+#!/usr/bin/perl
+
+# (C) Maxim Dounin
+# (C) Sergey Kandaurov
+# (C) Nginx, Inc.
+
+# Tests for http proxy module with unix socket.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+eval { require IO::Socket::UNIX; };
+plan(skip_all => 'IO::Socket::UNIX not installed') if $@;
+
+my $t = Test::Nginx->new()->has(qw/http proxy/)->plan(4);
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080;
+        server_name  localhost;
+
+        location / {
+            proxy_pass http://unix:/%%TESTDIR%%/unix.sock;
+            proxy_read_timeout 1s;
+            proxy_connect_timeout 2s;
+        }
+
+        location /var {
+            proxy_pass http://$arg_b;
+            proxy_read_timeout 1s;
+        }
+    }
+}
+
+EOF
+
+my $d = $t->testdir();
+
+$t->run_daemon(\&http_daemon, $d);
+$t->run();
+
+# wait for unix socket to appear
+
+for (1 .. 50) {
+	last if -S "$d/unix.sock";
+	select undef, undef, undef, 0.1;
+}
+
+###############################################################################
+
+like(http_get('/'), qr/SEE-THIS/, 'proxy request');
+like(http_get('/multi'), qr/AND-THIS/, 'proxy request with multiple packets');
+
+unlike(http_head('/'), qr/SEE-THIS/, 'proxy head request');
+
+TODO: {
+local $TODO = 'not yet';
+
+like(http_get("/var?b=unix:/$d/unix.sock:/"), qr/SEE-THIS/, 'proxy variables');
+
+}
+
+###############################################################################
+
+sub http_daemon {
+	my ($d) = @_;
+
+	my $server = IO::Socket::UNIX->new(
+		Proto => 'tcp',
+		Local => "$d/unix.sock",
+		Listen => 5,
+		Reuse => 1
+	)
+		or die "Can't create listening socket: $!\n";
+
+	local $SIG{PIPE} = 'IGNORE';
+
+	while (my $client = $server->accept()) {
+		$client->autoflush(1);
+
+		my $headers = '';
+		my $uri = '';
+
+		while (<$client>) {
+			$headers .= $_;
+			last if (/^\x0d?\x0a?$/);
+		}
+
+		$uri = $1 if $headers =~ /^\S+\s+([^ ]+)\s+HTTP/i;
+
+		if ($uri eq '/') {
+			print $client <<'EOF';
+HTTP/1.1 200 OK
+Connection: close
+
+EOF
+			print $client "TEST-OK-IF-YOU-SEE-THIS"
+				unless $headers =~ /^HEAD/i;
+
+		} elsif ($uri eq '/multi') {
+
+			print $client <<"EOF";
+HTTP/1.1 200 OK
+Connection: close
+
+TEST-OK-IF-YOU-SEE-THIS
+EOF
+
+			select undef, undef, undef, 0.1;
+			print $client 'AND-THIS';
+
+		} else {
+
+			print $client <<"EOF";
+HTTP/1.1 404 Not Found
+Connection: close
+
+Oops, '$uri' not found
+EOF
+		}
+
+		close $client;
+	}
+}
+
+###############################################################################