# -*-perl-*-

use strict;
use Test::More;
use Cache::Memcached;
use IO::Socket::INET;

my $testaddr = "127.0.0.1:11211";
my $msock = IO::Socket::INET->new(PeerAddr => $testaddr,
                                  Timeout  => 3);
if ($msock) {
    plan tests => 14;
} else {
    plan skip_all => "No memcached instance running at $testaddr\n";
    exit 0;
}

my $memd = Cache::Memcached->new({
    servers   => [ $testaddr ],
    namespace => "Cache::Memcached::t/$$/" . (time() % 100) . "/",
});


ok($memd->set("key1", "val1"), "set succeeded");

is($memd->get("key1"), "val1", "get worked");
ok(! $memd->add("key1", "val-replace"), "add properly failed");
ok($memd->add("key2", "val2"), "add worked on key2");
is($memd->get("key2"), "val2", "get worked");

ok($memd->replace("key2", "val-replace"), "replace worked");
ok(! $memd->replace("key-noexist", "bogus"), "replace failed");

ok($memd->set("key1", "1"), "set before append/prepend");
ok($memd->append("key1", "2"), "append worked");
ok($memd->prepend("key1", "3"), "prepend worked");
is($memd->get("key1"), "312", "append/prepend result check");

my $stats = $memd->stats;
ok($stats, "got stats");
is(ref $stats, "HASH", "is a hashref");


# also make one without a hashref
my $mem2 = Cache::Memcached->new(
                                 servers   => [ ],
                                 debug     => 1,
                                 );
ok($mem2->{debug}, "debug is set on alt constructed instance");