view limit_req_dry_run.t @ 1961:fe6f22da53ec default tip

Tests: tests for usage of discarded body. The client_max_body_size limit should be ignored when the request body is already discarded. In HTTP/1.x, this is done by checking the r->discard_body flag when the body is being discarded, and because r->headers_in.content_length_n is 0 when it's already discarded. This, however, does not happen with HTTP/2 and HTTP/3, and therefore "error_page 413" does not work without relaxing the limit. Further, with proxy_pass, r->headers_in.content_length_n is used to determine length of the request body, and therefore is not correct if discarding of the request body isn't yet complete. While discarding the request body, r->headers_in.content_length_n contains the rest of the body to discard (or, in case of chunked request body, the rest of the current chunk to discard). Similarly, the $content_length variable uses r->headers_in.content_length if available, and also incorrect. The $content_length variable is used when proxying with fastcgi_pass, grpc_pass, and uwsgi_pass (scgi_pass uses the value calculated based on the actual request body buffers, and therefore works correctly).
author Maxim Dounin <mdounin@mdounin.ru>
date Sat, 27 Apr 2024 18:55:50 +0300
parents 5ac6efbe5552
children
line wrap: on
line source

#!/usr/bin/perl

# (C) Sergey Kandaurov
# (C) Nginx, Inc.

# Tests for nginx limit_req module, limit_req_dry_run directive.

###############################################################################

use warnings;
use strict;

use Test::More;

BEGIN { use FindBin; chdir($FindBin::Bin); }

use lib 'lib';
use Test::Nginx;

###############################################################################

select STDERR; $| = 1;
select STDOUT; $| = 1;

my $t = Test::Nginx->new()->has(qw/http limit_req/);

$t->write_file_expand('nginx.conf', <<'EOF');

%%TEST_GLOBALS%%

daemon off;

events {
}

http {
    %%TEST_GLOBALS_HTTP%%

    limit_req_zone  $binary_remote_addr  zone=one:1m   rate=1r/m;

    log_format test $uri:$limit_req_status;

    server {
        listen       127.0.0.1:8080;
        server_name  localhost;

        limit_req_dry_run  on;
        add_header X-Status $limit_req_status always;
        access_log %%TESTDIR%%/test.log test;

        location /delay {
            limit_req    zone=one  burst=2;
        }

        location /reject {
            limit_req    zone=one;
        }

        location /reject/off {
            limit_req    zone=one;

            limit_req_dry_run off;
        }

        location / { }
    }
}

EOF

$t->write_file('delay', 'SEE-THIS');
$t->write_file('reject', 'SEE-THIS');
$t->run()->plan(8);

###############################################################################

like(http_get('/delay'), qr/ 200 .*PASSED/ms, 'dry run - passed');
like(http_get('/delay'), qr/ 200 .*DELAYED_DRY_RUN/ms, 'dry run - delayed');
like(http_get('/reject'), qr/ 200 .*REJECTED_DRY_RUN/ms, 'dry run - rejected');

like(http_get('/reject/off'), qr/ 503 .*REJECTED/ms, 'dry run off - rejected');

unlike(http_get('/'), qr/X-Status/, 'no limit');

$t->stop();

like($t->read_file('error.log'), qr/delaying request, dry/, 'log - delay');
like($t->read_file('error.log'), qr/limiting requests, dry/, 'log - reject');

like($t->read_file('test.log'), qr|^/:-|m, 'log - not found');

###############################################################################