--- a/h2_proxy_cache.t
+++ b/h2_proxy_cache.t
@@ -23,7 +23,7 @@ use Test::Nginx::HTTP2;
 select STDERR; $| = 1;
 select STDOUT; $| = 1;
 
-my $t = Test::Nginx->new()->has(qw/http http_v2 proxy cache/)->plan(11)
+my $t = Test::Nginx->new()->has(qw/http http_v2 proxy cache/)->plan(12)
 	->write_file_expand('nginx.conf', <<'EOF');
 
 %%TEST_GLOBALS%%
@@ -38,6 +38,10 @@ http {
 
     proxy_cache_path %%TESTDIR%%/cache    keys_zone=NAME:1m;
 
+    # quit unfixed nginx timely on different linuces
+    http2_idle_timeout 2s;
+    http2_recv_timeout 2s;
+
     server {
         listen       127.0.0.1:8080 http2;
         listen       127.0.0.1:8081;
@@ -145,4 +149,33 @@ push @$frames, $_ for @{$s->read(all => 
 ok(!grep ({ $_->{type} eq "DATA" } @$frames),
 	'proxy cache HEAD buffering off - no body');
 
+# client cancels stream with a cacheable request that was sent to upstream
+# HEADERS should not be produced for the canceled stream
+
+$s = Test::Nginx::HTTP2->new();
+$sid = $s->new_stream({ path => '/cache/t.html?3' });
+
+$s->h2_rst($sid, 8);
+
+$frames = $s->read(all => [{ sid => $sid, fin => 0x4 }], wait => 0.2);
+
+TODO: {
+local $TODO = 'not yet';
+
+ok(!(grep { $_->{type} eq "HEADERS" } @$frames), 'no headers');
+
+}
+
+# client closes connection after sending a cacheable request producing alert
+
+$t->todo_alerts();
+
+$s = Test::Nginx::HTTP2->new();
+$sid = $s->new_stream({ path => '/cache/t.html?4' });
+
+undef $s;
+select undef, undef, undef, 0.2;
+
+$t->stop();
+
 ###############################################################################

new file mode 100644
--- /dev/null
+++ b/h2_ssl.t
@@ -0,0 +1,131 @@
+#!/usr/bin/perl
+
+# (C) Sergey Kandaurov
+# (C) Nginx, Inc.
+
+# Tests for HTTP/2 protocol with ssl.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+use Test::Nginx::HTTP2;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+eval { require IO::Socket::SSL; };
+plan(skip_all => 'IO::Socket::SSL not installed') if $@;
+
+my $t = Test::Nginx->new()->has(qw/http http_ssl http_v2/)
+	->has_daemon('openssl')->plan(1);
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    server {
+        listen       127.0.0.1:8080 http2 ssl;
+        server_name  localhost;
+
+        ssl_certificate_key localhost.key;
+        ssl_certificate localhost.crt;
+
+        location / { }
+    }
+}
+
+EOF
+
+$t->write_file('openssl.conf', <<EOF);
+[ req ]
+default_bits = 2048
+encrypt_key = no
+distinguished_name = req_distinguished_name
+[ req_distinguished_name ]
+EOF
+
+my $d = $t->testdir();
+
+foreach my $name ('localhost') {
+	system('openssl req -x509 -new '
+		. "-config '$d/openssl.conf' -subj '/CN=$name/' "
+		. "-out '$d/$name.crt' -keyout '$d/$name.key' "
+		. ">>$d/openssl.out 2>&1") == 0
+		or die "Can't create certificate for $name: $!\n";
+}
+
+$t->write_file('tbig.html',
+	join('', map { sprintf "XX%06dXX", $_ } (1 .. 500000)));
+
+open OLDERR, ">&", \*STDERR; close STDERR;
+$t->run();
+open STDERR, ">&", \*OLDERR;
+
+###############################################################################
+
+# client cancels 2nd stream after HEADERS has been created
+# while some unsent data was left in the SSL buffer
+# HEADERS frame may stuck in SSL buffer and won't be sent producing alert
+
+SKIP: {
+my $s = getconn(port(0));
+skip 'OpenSSL ALPN/NPN support required', 1 unless defined $s;
+
+ok($s, 'ssl connection');
+
+$t->todo_alerts();
+
+my $sid = $s->new_stream({ path => '/tbig.html' });
+
+select undef, undef, undef, 0.2;
+$s->h2_rst($sid, 8);
+
+$sid = $s->new_stream({ path => '/tbig.html' });
+
+select undef, undef, undef, 0.2;
+$s->h2_rst($sid, 8);
+
+$t->stop();
+
+}
+
+###############################################################################
+
+sub getconn {
+	my ($port) = @_;
+	my $s;
+
+	eval {
+		IO::Socket::SSL->can_alpn() or die;
+		$s = Test::Nginx::HTTP2->new($port, SSL => 1, alpn => 'h2');
+	};
+
+	return $s if defined $s;
+
+	eval {
+		IO::Socket::SSL->can_npn() or die;
+		$s = Test::Nginx::HTTP2->new($port, SSL => 1, npn => 'h2');
+	};
+
+	return $s;
+}
+
+###############################################################################

new file mode 100644
--- /dev/null
+++ b/h2_ssl_proxy_cache.t
@@ -0,0 +1,143 @@
+#!/usr/bin/perl
+
+# (C) Sergey Kandaurov
+# (C) Nginx, Inc.
+
+# Tests for HTTP/2 protocol with ssl and http proxy cache.
+
+###############################################################################
+
+use warnings;
+use strict;
+
+use Test::More;
+
+BEGIN { use FindBin; chdir($FindBin::Bin); }
+
+use lib 'lib';
+use Test::Nginx;
+use Test::Nginx::HTTP2;
+
+###############################################################################
+
+select STDERR; $| = 1;
+select STDOUT; $| = 1;
+
+eval { require IO::Socket::SSL; };
+plan(skip_all => 'IO::Socket::SSL not installed') if $@;
+
+my $t = Test::Nginx->new()->has(qw/http http_ssl http_v2 proxy cache shmem/)
+	->has_daemon('openssl');
+
+$t->todo_alerts();
+
+$t->write_file_expand('nginx.conf', <<'EOF');
+
+%%TEST_GLOBALS%%
+
+daemon off;
+
+events {
+}
+
+http {
+    %%TEST_GLOBALS_HTTP%%
+
+    proxy_cache_path   %%TESTDIR%%/cache  keys_zone=NAME:1m;
+
+    server {
+        listen       127.0.0.1:8080 http2 ssl sndbuf=32k;
+        server_name  localhost;
+
+        ssl_certificate_key localhost.key;
+        ssl_certificate localhost.crt;
+
+        send_timeout 1s;
+
+        location / {
+            proxy_pass   http://127.0.0.1:8081;
+            proxy_cache  NAME;
+        }
+    }
+
+    server {
+        listen       127.0.0.1:8081 sndbuf=64k;
+        server_name  localhost;
+
+        location / { }
+    }
+}
+
+EOF
+
+$t->write_file('openssl.conf', <<EOF);
+[ req ]
+default_bits = 2048
+encrypt_key = no
+distinguished_name = req_distinguished_name
+[ req_distinguished_name ]
+EOF
+
+my $d = $t->testdir();
+
+foreach my $name ('localhost') {
+	system('openssl req -x509 -new '
+		. "-config '$d/openssl.conf' -subj '/CN=$name/' "
+		. "-out '$d/$name.crt' -keyout '$d/$name.key' "
+		. ">>$d/openssl.out 2>&1") == 0
+		or die "Can't create certificate for $name: $!\n";
+}
+
+$t->write_file('tbig.html',
+	join('', map { sprintf "XX%06dXX", $_ } (1 .. 500000)));
+
+open OLDERR, ">&", \*STDERR; close STDERR;
+$t->run();
+open STDERR, ">&", \*OLDERR;
+
+plan(skip_all => 'no ALPN/NPN negotiation') unless defined getconn(port(0));
+$t->plan(1);
+
+###############################################################################
+
+# client cancels stream with a cacheable request sent to upstream causing alert
+
+my $s = getconn(port(0));
+ok($s, 'ssl connection');
+
+my $sid = $s->new_stream();
+$s->h2_rst($sid, 8);
+
+# large response may stuck in SSL buffer and won't be sent producing alert
+
+my $s2 = getconn(port(0));
+$sid = $s2->new_stream({ path => '/tbig.html' });
+$s2->h2_window(2**30, $sid);
+$s2->h2_window(2**30);
+
+select undef, undef, undef, 0.2;
+
+$t->stop();
+
+###############################################################################
+
+sub getconn {
+	my ($port) = @_;
+	my $s;
+
+	eval {
+		IO::Socket::SSL->can_alpn() or die;
+		$s = Test::Nginx::HTTP2->new($port, SSL => 1, alpn => 'h2');
+	};
+
+	return $s if defined $s;
+
+	eval {
+		IO::Socket::SSL->can_npn() or die;
+		$s = Test::Nginx::HTTP2->new($port, SSL => 1, npn => 'h2');
+	};
+
+	return $s;
+}
+
+###############################################################################